// Exemple d'animation avec SciLab
// Simulation de figures de Lissajous.

// Données :
clf;  // efface le graphique précédent.  On peut ne pas l'effacer et tracer d'autres traces.
R = 2*%pi;
N = 200;
t = linspace(0, R, N);
wx = 3; // pulsation du signal en x
wy = 5; // pulsation du signal en y
Px = cos(wx*t)
Py = sin(wy*t)

f=gcf();  // = get("current_figure");
f.background = color(32, 32, 32); 

aaa = gca();
aaa.background=color(0, 0, 0);
aaa.data_bounds=[-1.5, -1.5 ; 1.5, 1.5];
aaa.isoview="on";  // axes x et y ont la même échelle
aaa.margins = [0.01, 0.01, 0.01, 0.01];  // pour agrandir l'affichage.
aaa.box = "on"; // pour tracer une boîte autour du graphique.
// lorsque la fenêtre graphique existe,
// tapez  aaa  dans la console Scilab pour plus d'options.

// trace du point de la siprale
plot(Px, Py, "w"); 
eee1 = gce();
eee1.children.thickness = 2;

//aaa.axes_visible = ["off", "off", "off"];
  
for j=1:315
  drawlater();
  Px =  cos(wx*t);
  Py =  sin(wy*t + j/100);  // j/100 déphase le signal.
  eee1.children(1).data = [Px; Py]';
  drawnow();
  end;
  
  
